divert(-1)
#
# Copyright (c) 2001 Sendmail, Inc. and its suppliers.
#	All rights reserved.
#
# By using this file, you agree to the terms and conditions set
# forth in the LICENSE file which can be found at the top level of
# the sendmail distribution.
#
# queuegroupx.m4 based on queuegroup.m4
#
# (c) Murty Rompalli 
# murty@solar . m u r t y . net  
#
# 8/22/2002

divert(0)
VERSIONID(`$Id: queuegroupx.m4,v 1.0 2002/16/08 Murty_Rompalli Exp $')
divert(-1)

ifdef(`_ACCESS_TABLE_', `',
	`errprint(`*** ERROR: FEATURE(`queuegroupx') requires FEATURE(`access_db')
')')

LOCAL_RULESETS

Squeuegroup

R< $+ >			$1					Prepare sender/recpt
R$+			$: $&f $| $1
R< $* > $| $+		$1 $| $2
R$| $+			$: @ $| $1
R$* @ $* $| $* @ $*	$@ $>queuegroup1 $1 @ $2 $| $3 @ $4
ifelse(len(X`'_ARG_),`1',
`R$*			$@',
`R$*			$# _ARG_')

Squeuegroup1

R@  $| $+		$: <> $| $1				sen/rec check
R$+ $| $+		$: $(access QFTO:$1<@>$2 $: $1 $| $2 $)
R$+ $| $+		$@ $>queuegroup2 $1 $| $2
R$+			$# $1

Squeuegroup2

R<> $| $+		$@ $>queuegroup3 $1			sender check
R$+ @ $+ $| $+		$: $3 $| $>SearchList <! qfrm> $| <F:$1@$2> <D:$2> <>
R$+ $| <?>		$@ $>queuegroup4 $1
R$+ $| <$+>		$# $2

Squeuegroup3

R$+			$: $1 $| $(access QFRM:<> $: <> $)	null sender check
R$+ $| <>		$@ $>queuegroup4 $1
R$+ $| $+		$# $2

Squeuegroup4

R$+ @ $+		$: $>SearchList <! qgrp> $| <F:$1@$2> <D:$2> <>
ifelse(len(X`'_ARG_),`1',
`R<?>			$@',
`R<?>			$# _ARG_')
R<$+>			$# $1					rec check

Squeuegroupd

R$* $$| $*		$: $1 $| $2				For debugging only
R< $* > $| $*		$1 $| $2
R$* $| < $* >		$1 $| $2
R$| $*			$: @ $| $1
R$* $|			$@ $>queuegroup2 $1 $| @
R$+ $| $+		$@ $>queuegroup1 $1 $| $2
R<$*>			$1
R$+ @  $+		$@ $>queuegroup4 $1 @  $2
ifelse(len(X`'_ARG_),`1',
`R$*			$@',
`R$*			$# _ARG_')